ATtiny85 timer programming using the Watchdog Timer


This Arduino sketch uses the watchdog timer on the ATtiny85 to interrupt every second to pulse the LED:

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
#include <avr/io.h>
#include <avr/wdt.h>
#include <avr/sleep.h>
#include <avr/interrupt.h>

bool led = true;

void setup() {
  // Misc setup
  pinMode(1, OUTPUT);
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);

  // Setup watchdog timer to interrupt every second
  MCUSR &= ~_BV(WDRF);
  WDTCR |= (_BV(WDCE) | _BV(WDE));
  WDTCR = _BV(WDP1) | _BV(WDP2);
  WDTCR |= _BV(WDIE);
  sei();
}

ISR(WDT_vect) {
  sleep_disable();
  digitalWrite(1, led ? HIGH : LOW);
  led = !led;
  // Execution continues in loop()
}

void loop() {
  sleep_enable();
  sleep_cpu(); // MCU goes to sleep here; wake up by watchdog timer interrupt
}

The advantage of this approach is I can use the SLEEP_MODE_PWR_DOWN mode to put the MCU to sleep to save the maximum amount of power when there is nothing to be done. The watchdog timer clocks on its own 128kHz oscillator, and can be setup to wake the MCU every second via an interrupt, something that cannot be done using Timer0 or Timer1.

Unfortunately, it appears the 128kHz oscillator  is not terribly accurate and can range between between 96 and 119kHz. In my test, the LED pulsed slightly slower than 1Hz, and start losing track after about 15 second ticks. There is also no way to calibrate the watchdog timer oscillator as far as I can tell.


Comments

Popular posts from this blog

Adding "Stereo Mixer" to Windows 7 with Conexant sound card

Roomba navigation algorithm

Hacking an analog clock to sync with NTP - Part 5