Skip to main content

Attiny85 timer programming using Timer1

This Arduino sketch uses Timer1 to drive the LED blinker:

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
/*
 * Program ATTiny85 to blink LED connected to PB1 at 1s interval.
 * Assumes ATTiny85 is running at 1MHz internal clock speed.
 */

#include <avr/io.h>
#include <avr/wdt.h>
#include <avr/sleep.h>
#include <avr/interrupt.h>

bool timer1 = false, led = true;

// Interrupt service routine for timer1
ISR(TIMER1_COMPA_vect)
{
  timer1 = true;
}

void setup() {

  // Setup output pins
  pinMode(1, OUTPUT);
  digitalWrite(1, led);
  set_sleep_mode(SLEEP_MODE_IDLE);

  // Setup timer1 to interrupt every second
  TCCR1 = 0; // Stop timer
  TCNT1 = 0; // Zero timer
  GTCCR = _BV(PSR1); // Reset prescaler
  OCR1A = 243; // T = prescaler / 1MHz = 0.004096s; OCR1A = (1s/T) - 1 = 243
  OCR1C = 243; // Set to same value to reset timer1 to 0 after a compare match
  TIMSK = _BV(OCIE1A); // Interrupt on compare match with OCR1A
  
  // Start timer in CTC mode; prescaler = 4096; 
  TCCR1 = _BV(CTC1) | _BV(CS13) | _BV(CS12) | _BV(CS10);
  sei();
}

void loop() {
  if (timer1) {
    timer1 = false;
    led = !led;
    digitalWrite(1, led);
  }
  sleep_enable();
  sleep_cpu(); // CPU goes to sleep here; will be woken up by timer1 interrupt
}

The internal RC oscillator can have a factory variance of up to 10%. I observe that my blinker pulsed slightly faster than 1Hz.

Thankfully, unlike the watchdog oscillator, the internal RC oscillator can be calibrated by using the OSCCAL register, or adjusting the value of OCR1A. I believe it should not be too difficult to automatically calibrate the oscillator between NTP calls by taking the difference in actual time and clock time (in seconds) and adjust OCR1A accordingly to get as close to 1Hz as possible.

So on initial startup, the ESPCLOCK may not be pulsing at 1Hz, but after 15 or 30 minutes, it should be fully calibrated.

The downside with this approach is we can only use SLEEP_MODE_IDLE to keep Timer1 running during sleep, which is not as power efficient  as using the Watchdog Timer.

Comments

  1. Hi .help me to change the function from arduino codes at attyni85 usb .please help with .thanks
    void setup() {
    // put your setup code here, to run once:

    //timer2
    OCR2A = 127; //50% duty cycle
    TCCR2A = _BV(COM2A0) | _BV(WGM21) | _BV(WGM20); //toggle output, fast PWM mode
    TCCR2B = _BV(WGM22) | _BV(CS21) | _BV(CS20); // fast PWM mode, prescale 1:64
    pinMode(11, OUTPUT);

    }

    void loop()
    {

    delay(200); //duration of each frequency
    OCR2A += 10; //step size of frequency change
    if(OCR2A >= 245){OCR2A = 10; } //range of sweep, 245 is max.

    }

    ReplyDelete
  2. there are only 2 timers on attiny85, timer0 and timer1

    ReplyDelete

Post a Comment

Popular posts from this blog

Update: Line adapter for Ozito Blade Trimmer

Update (Dec 2021): If you access to a 3D printer, I would now recommend this solution , which makes it super easy to replace the trimmer line. I have been using it for a few months now with zero issue.

Line adapter for Ozito Blade Trimmer

This is an adapter for Ozito 18V battery trimmer (and possibly some Bosch trimmers as well) that uses a plastic blade for cutting. It lets you insert a 2.4mm trimmer line (about 8cm long) and use that for cutting. Simply cut a length of trimmer line and briefly heat up one end with a lighter so that a little bulb is formed. Then insert the trimmer line into the adapter and slot that into the trimmer as per normal. Make sure the trimmer line is not so long that it touches the safety guard. If that is the case, simply trim off any excess with a cutter or scissors. This part is best printed using PETG, which is a tougher and more flexible material. PLA is more rigid and breaks more easily. However, even with PETG, it will still break when it hits something really hard. Since this takes only 0.5m of material and 15 minutes to print, I will usually print a batch of nine at a time at very little cost. The blades that they sell do not break when it hits a hard object, but